[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: [AUCTeX] Beamer
From: |
Sven Bretfeld |
Subject: |
Re: [AUCTeX] Beamer |
Date: |
Fri, 18 Apr 2008 10:40:02 +0200 |
User-agent: |
Gnus/5.110006 (No Gnus v0.6) Emacs/23.0.50 (gnu/linux) |
Hi
"Salvatore Enrico Indiogine" <address@hidden> writes:
> Are there any features for beamer, such as commands that can insert a
> frame in text without having to type it all out? Any other beamer
> suggestions?
There are some latex-beamer specific pieces of code I gathered from
different places in my .emacs. Here is a copy.
Greetings
Sven
;;--------------------------------------------
;; LaTeX-Beamer
;;--------------------------------------------
(eval-after-load "tex"
'(TeX-add-style-hook "beamer" 'my-beamer-mode))
(setq TeX-region "regionsje")
(defun my-beamer-mode ()
"My adds on for when in beamer."
;; when in a Beamer file I want to use pdflatex.
;; Thanks to Ralf Angeli for this.
(TeX-PDF-mode 1) ;turn on PDF mode.
;; Tell reftex to treat \lecture and \frametitle as section commands
;; so that C-c = gives you a list of frametitles and you can easily
;; navigate around the list of frames.
;; If you change reftex-section-level, reftex needs to be reset so that
;; reftex-section-regexp is correctly remade.
(require 'reftex)
(set (make-local-variable 'reftex-section-levels)
'(("lecture" . 1) ("frametitle" . 2)))
(reftex-reset-mode)
;; add some extra functions.
(define-key LaTeX-mode-map "\C-cf" 'beamer-template-frame)
(define-key LaTeX-mode-map "\C-\M-x" 'tex-frame)
(define-key LaTeX-mode-map "\C-cn" 'beamer-make-note)
)
(defun tex-frame ()
"Run pdflatex on current frame.
Frame must be declared as an environment."
(interactive)
(let (beg)
(save-excursion
(search-backward "\\begin{frame}")
(setq beg (point))
(forward-char 1)
(LaTeX-find-matching-end)
(TeX-pin-region beg (point))
(letf (( (symbol-function 'TeX-command-query) (lambda (x) "LaTeX")))
(TeX-command-region))
)
))
(defun beamer-template-frame ()
"Create a simple template and move point to after \\frametitle."
(interactive)
(LaTeX-environment-menu "frame")
(insert "\\frametitle{}")
(backward-char 1))
(defun beamer-make-note ()
"Create a note template and move point to the first item."
(interactive)
(insert "\\note[itemize]{
\\item
%
}")
(backward-char 4))
pgpDds7EUyWGp.pgp
Description: PGP signature
- [AUCTeX] Beamer, Salvatore Enrico Indiogine, 2008/04/17
- Re: [AUCTeX] Beamer,
Sven Bretfeld <=