Re: Forcing complete expansion of a PATH variable

[Raja R Harinath]

address@hidden (Joshua Kwan) writes:
[snip]
> Now I have added AC_SUBST_DIR(musicpath) after these lines.
>
> But something weird happens now:
>
> ./configure: line 3594: musicpath: command not found
>
> This doesn't affect the success of configure, but I wonder why it is
> there? I looked in configure itself and lo there it was:
>
>         musicpath
>         musicpath=`(
>             test "x$prefix" = xNONE && prefix="$ac_default_prefix"
>             test "x$exec_prefix" = xNONE && exec_prefix="${prefix}"
>             eval echo \""$musicpath"\"   
>         )`
>
> But I've added nothing but that one AC_SUBST_DIR. I am using the m4 code
> verbatim from the site ou have given me. Do you know what's up?

The code at http://ac-archive.sf.net/Miscellaneous/ac_subst_dir.html
says:

    AC_DEFUN([AC_SUBST_DIR], [
            ifelse($2, , $1, $1="[$]$2")
            $1=`(
                test "x$prefix" = xNONE && prefix="$ac_default_prefix"
                test "x$exec_prefix" = xNONE && exec_prefix="${prefix}"
                eval echo \""[$]$1"\"
            )`
            AC_SUBST($1)
    ])

Try this instead:

    AC_DEFUN([AC_SUBST_DIR], [
            ifelse($2,,,$1="[$]$2")
            $1=`(
                test "x$prefix" = xNONE && prefix="$ac_default_prefix"
                test "x$exec_prefix" = xNONE && exec_prefix="${prefix}"
                eval echo \""[$]$1"\"
            )`
            AC_SUBST($1)
    ])

- Hari
-- 
Raja R Harinath ------------------------------ address@hidden