Re: proposed gnulib-related additions to Autoconf

[Ralf Wildenhues]

Addition to my previous review:

* Paul Eggert wrote on Wed, Mar 01, 2006 at 01:48:54AM CET:
> 
> Index: lib/autoconf/specific.m4
> ===================================================================
> RCS file: /cvsroot/autoconf/autoconf/lib/autoconf/specific.m4,v
> retrieving revision 1.363
> diff -p -u -r1.363 specific.m4
> --- lib/autoconf/specific.m4  24 Jan 2006 00:20:15 -0000      1.363
> +++ lib/autoconf/specific.m4  1 Mar 2006 19:32:24 -0000

> @@ -379,6 +379,41 @@ esac
>  matches *mingw32*])# AC_MINGW32
>  
>  
> +# AC_USE_SYSTEM_EXTENSIONS
> +# ------------------------
> +# Enable extensions on systems that normally disable them,
> +# typically due to standards-conformance issues.
> +AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS],
> +[
> +  AC_BEFORE([$0], [AC_COMPILE_IFELSE])
> +  AC_BEFORE([$0], [AC_RUN_IFELSE])
> +
> +  AC_REQUIRE([AC_GNU_SOURCE])
> +  AC_REQUIRE([AC_AIX])
> +  AC_REQUIRE([AC_MINIX])
> +
> +  AH_VERBATIM([__EXTENSIONS__],
> +[/* Enable extensions on Solaris.  */
> +#ifndef __EXTENSIONS__
> +# undef __EXTENSIONS__
> +#endif
> +#ifndef _POSIX_PTHREAD_SEMANTICS
> +# undef _POSIX_PTHREAD_SEMANTICS
> +#endif])
> +  AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
> +    [ac_cv_safe_to_define___extensions__],
> +    [AC_COMPILE_IFELSE(
> +       [AC_LANG_PROGRAM([
> +       #define __EXTENSIONS__ 1
> +       AC_INCLUDES_DEFAULT])],
> +       [ac_cv_safe_to_define___extensions__=yes],
> +       [ac_cv_safe_to_define___extensions__=no])])
> +  test $ac_cv_safe_to_define___extensions__ == yes &&

Please  s,==,=,  to make this pass test on HPUX.
I'd also double-quote the first test operand, but
that's a style issue.

> +    AC_DEFINE([__EXTENSIONS__])
> +  AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
> +])
> +
> +
>  
>  
>  ## -------------------------- ##

Cheers,
Ralf