Re: new module 'cbrtl'

[Bruno Haible]

> 2012-02-29  Bruno Haible  <address@hidden>
> 
>       New module 'cbrtl'.

The IEEE tests show that on IRIX 6.5
  cbrtf(-0.0) = -Inf    (ouch!!)
  cbrtl(-0.0) = +0.0

The patches are similar; here's the second one.


2012-02-29  Bruno Haible  <address@hidden>

        cbrtl-ieee: Work around test failure on IRIX 6.5.
        * m4/cbrtl-ieee.m4: New file.
        * m4/cbrtl.m4 (gl_FUNC_CBRTL): If gl_FUNC_CBRTL_IEEE is present,
        test whether cbrtl works with a minus zero argument. Replace it if not.
        * lib/math.in.h (cbrtl): Override if REPLACE_CBRTL is 1.
        * m4/math_h.m4 (gl_MATH_H_DEFAULTS): Initialize REPLACE_CBRTL.
        * modules/math (Makefile.am): Substitute REPLACE_CBRTL.
        * modules/cbrtl (configure.ac): Consider REPLACE_CBRTL.
        (Depends-on): Update conditions.
        * modules/cbrtl-ieee (Files): Add m4/cbrtl-ieee.m4, m4/minus-zero.m4,
        m4/signbit.m4.
        (configure.ac): Invoke gl_FUNC_CBRTL_IEEE.
        * lib/cbrtl.c (cbrtl) [IRIX]: Avoid an unnecessary addition.
        * doc/posix-functions/cbrtl.texi: Mention the cbrtl-ieee module.

============================== m4/cbrtl-ieee.m4 ==============================
# cbrtl-ieee.m4 serial 1
dnl Copyright (C) 2012 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl This macro is in a separate file (not in cbrtl.m4 and not inlined in the
dnl module description), so that gl_FUNC_CBRTL can test whether 'aclocal' has
dnl found uses of this macro.

AC_DEFUN([gl_FUNC_CBRTL_IEEE],
[
  m4_divert_text([INIT_PREPARE], [gl_cbrtl_required=ieee])
  AC_REQUIRE([gl_FUNC_CBRTL])
])
==============================================================================
--- doc/posix-functions/cbrtl.texi.orig Thu Mar  1 04:52:39 2012
+++ doc/posix-functions/cbrtl.texi      Thu Mar  1 04:02:06 2012
@@ -4,9 +4,9 @@
 
 POSIX specification:@* 
@url{http://www.opengroup.org/onlinepubs/9699919799/functions/cbrtl.html}
 
-Gnulib module: cbrtl
+Gnulib module: cbrtl or cbrtl-ieee
 
-Portability problems fixed by Gnulib:
+Portability problems fixed by either Gnulib module @code{cbrtl} or 
@code{cbrtl-ieee}
 @itemize
 @item
 This function is missing on some platforms:
@@ -16,6 +16,14 @@
 IRIX 6.5.
 @end itemize
 
+Portability problems fixed by Gnulib module @code{cbrtl-ieee}:
address@hidden
address@hidden
+This function returns a positive zero for a minus zero argument
+on some platforms:
+IRIX 6.5.
address@hidden itemize
+
 Portability problems not fixed by Gnulib:
 @itemize
 @end itemize
--- lib/cbrtl.c.orig    Thu Mar  1 04:52:39 2012
+++ lib/cbrtl.c Thu Mar  1 04:48:02 2012
@@ -140,7 +140,13 @@
       return x;
     }
   else
-    return x + x;
+    {
+# ifdef __sgi /* so that when x == -0.0L, the result is -0.0L not +0.0L */
+      return x;
+# else
+      return x + x;
+# endif
+    }
 }
 
 #endif
--- lib/math.in.h.orig  Thu Mar  1 04:52:39 2012
+++ lib/math.in.h       Thu Mar  1 03:51:22 2012
@@ -326,10 +326,19 @@
 #endif
 
 #if @GNULIB_CBRTL@
-# if address@hidden@
+# if @REPLACE_CBRTL@
+#  if !(defined __cplusplus && defined GNULIB_NAMESPACE)
+#   undef cbrtl
+#   define cbrtl rpl_cbrtl
+#  endif
+_GL_FUNCDECL_RPL (cbrtl, long double, (long double x));
+_GL_CXXALIAS_RPL (cbrtl, long double, (long double x));
+# else
+#  if address@hidden@
 _GL_FUNCDECL_SYS (cbrtl, long double, (long double x));
-# endif
+#  endif
 _GL_CXXALIAS_SYS (cbrtl, long double, (long double x));
+# endif
 _GL_CXXALIASWARN (cbrtl);
 #elif defined GNULIB_POSIXCHECK
 # undef cbrtl
--- m4/cbrtl.m4.orig    Thu Mar  1 04:52:39 2012
+++ m4/cbrtl.m4 Thu Mar  1 04:47:28 2012
@@ -1,4 +1,4 @@
-# cbrtl.m4 serial 1
+# cbrtl.m4 serial 2
 dnl Copyright (C) 2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -6,6 +6,7 @@
 
 AC_DEFUN([gl_FUNC_CBRTL],
 [
+  m4_divert_text([DEFAULTS], [gl_cbrtl_required=plain])
   AC_REQUIRE([gl_MATH_H_DEFAULTS])
   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
   AC_REQUIRE([gl_FUNC_CBRT])
@@ -21,9 +22,55 @@
     dnl Also check whether it's declared.
     dnl IRIX 6.5 has cbrtl() in libm but doesn't declare it in <math.h>.
     AC_CHECK_DECL([cbrtl], , [HAVE_DECL_CBRTL=0], [[#include <math.h>]])
+    m4_ifdef([gl_FUNC_CBRTL_IEEE], [
+      if test $gl_cbrtl_required = ieee && test $REPLACE_CBRTL = 0; then
+        AC_CACHE_CHECK([whether cbrtl works according to ISO C 99 with IEC 
60559],
+          [gl_cv_func_cbrtl_ieee],
+          [
+            save_LIBS="$LIBS"
+            LIBS="$LIBS $CBRTL_LIBM"
+            AC_RUN_IFELSE(
+              [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <math.h>
+]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
+]gl_LONG_DOUBLE_SIGNBIT_CODE[
+static long double dummy (long double x) { return 0; }
+int main (int argc, char *argv[])
+{
+  extern
+  #ifdef __cplusplus
+  "C"
+  #endif
+  long double cbrtl (long double);
+  long double (*my_cbrtl) (long double) = argc ? cbrtl : dummy;
+  long double f;
+  /* Test cbrtl(-0.0).
+     This test fails on IRIX 6.5.  */
+  f = my_cbrtl (minus_zerol);
+  if (!(f == 0.0L) || (signbitl (minus_zerol) && !signbitl (f)))
+    return 1;
+  return 0;
+}
+              ]])],
+              [gl_cv_func_cbrtl_ieee=yes],
+              [gl_cv_func_cbrtl_ieee=no],
+              [gl_cv_func_cbrtl_ieee="guessing no"])
+            LIBS="$save_LIBS"
+          ])
+        case "$gl_cv_func_cbrtl_ieee" in
+          *yes) ;;
+          *) REPLACE_CBRTL=1 ;;
+        esac
+      fi
+    ])
   else
     HAVE_CBRTL=0
     HAVE_DECL_CBRTL=0
+  fi
+  if test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; then
     dnl Find libraries needed to link lib/cbrtl.c.
     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
       CBRTL_LIBM="$CBRT_LIBM"
--- m4/math_h.m4.orig   Thu Mar  1 04:52:39 2012
+++ m4/math_h.m4        Thu Mar  1 03:52:08 2012
@@ -1,4 +1,4 @@
-# math_h.m4 serial 78
+# math_h.m4 serial 79
 dnl Copyright (C) 2007-2012 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -217,6 +217,7 @@
   HAVE_DECL_TRUNCF=1;          AC_SUBST([HAVE_DECL_TRUNCF])
   HAVE_DECL_TRUNCL=1;          AC_SUBST([HAVE_DECL_TRUNCL])
   REPLACE_CBRTF=0;             AC_SUBST([REPLACE_CBRTF])
+  REPLACE_CBRTL=0;             AC_SUBST([REPLACE_CBRTL])
   REPLACE_CEIL=0;              AC_SUBST([REPLACE_CEIL])
   REPLACE_CEILF=0;             AC_SUBST([REPLACE_CEILF])
   REPLACE_CEILL=0;             AC_SUBST([REPLACE_CEILL])
--- modules/cbrtl.orig  Thu Mar  1 04:52:39 2012
+++ modules/cbrtl       Thu Mar  1 03:55:21 2012
@@ -9,14 +9,14 @@
 
 Depends-on:
 math
-cbrt            [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE 
= 1]
-isfinite        [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE 
= 0]
-frexpl          [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE 
= 0]
-ldexpl          [test $HAVE_CBRTL = 0 && test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE 
= 0]
+cbrt            [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test 
$HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1]
+isfinite        [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test 
$HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
+frexpl          [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test 
$HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
+ldexpl          [{ test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; } && test 
$HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 0]
 
 configure.ac:
 gl_FUNC_CBRTL
-if test $HAVE_CBRTL = 0; then
+if test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; then
   AC_LIBOBJ([cbrtl])
 fi
 gl_MATH_MODULE_INDICATOR([cbrtl])
--- modules/cbrtl-ieee.orig     Thu Mar  1 04:52:39 2012
+++ modules/cbrtl-ieee  Thu Mar  1 04:11:30 2012
@@ -2,12 +2,16 @@
 cbrtl() function according to ISO C 99 with IEC 60559.
 
 Files:
+m4/cbrtl-ieee.m4
+m4/minus-zero.m4
+m4/signbit.m4
 
 Depends-on:
 cbrtl
 fpieee
 
 configure.ac:
+gl_FUNC_CBRTL_IEEE
 
 Makefile.am:
 
--- modules/math.orig   Thu Mar  1 04:52:39 2012
+++ modules/math        Thu Mar  1 03:52:50 2012
@@ -186,6 +186,7 @@
              -e 's|@''HAVE_DECL_TRUNCL''@|$(HAVE_DECL_TRUNCL)|g' \
          | \
          sed -e 's|@''REPLACE_CBRTF''@|$(REPLACE_CBRTF)|g' \
+             -e 's|@''REPLACE_CBRTL''@|$(REPLACE_CBRTL)|g' \
              -e 's|@''REPLACE_CEIL''@|$(REPLACE_CEIL)|g' \
              -e 's|@''REPLACE_CEILF''@|$(REPLACE_CEILF)|g' \
              -e 's|@''REPLACE_CEILL''@|$(REPLACE_CEILL)|g' \