Re: MinGW/autoconf

[Kevin Ryde]

Nils Durner <address@hidden> writes:
>
> It aborts after the warning and mingw.org doesn't provide a newer autoconf.

I was sure I'd wrestled it before and it was merely annoying but
harmless.

In any event normally I don't think there's any virtue in working with
old developer tools, but in this case we can modernize configure.in to
get around it.  I checked in the changes below.

        * configure.in (-lm): No need to suppress libm on mingw, it's not
        needed because it's empty, but including it does no harm.
        (-lm): Look for "cos" instead of "main", since cos and friends are the
        purpose of looking for libm.
        (winsock etc): Test $host = *-*-mingw* rather than $MINGW32, autoconf
        regards the latter as obsolete.
        (AC_MINGW32): Remove test, $MINGW32 now unused.
        (uint32_t): Look at HAVE_NETDB_H rather than hard-coding __MINGW32__
        in the test program.

The only bit to maybe wonder about is the -lm detection.  I'm pretty
sure AC_CHECK_LIB gets the right answer on its own, but I also know
libtool has had an AC_CHECK_LIBM doing some hard-coded suppressing of
-lm for beos, mingw, cygwin and darwin.


--- configure.in.~1.268.2.25.~  2006-12-15 10:15:59.000000000 +1100
+++ configure.in        2006-12-22 20:21:14.000000000 +1100
@@ -55,7 +55,6 @@
 
 dnl Some more checks for Win32
 AC_CYGWIN
-AC_MINGW32
 AC_LIBTOOL_WIN32_DLL
 
 AC_PROG_INSTALL
@@ -561,9 +560,11 @@
 AC_TYPE_SIGNAL
 AC_TYPE_MODE_T
 
-if test $MINGW32 = no; then
-       AC_CHECK_LIB(m, main)
-fi
+# On mingw -lm is empty, so this test is unnecessary, but it's
+# harmless so we don't hard-code to suppress it.
+#
+AC_CHECK_LIB(m, cos)
+
 AC_CHECK_FUNCS(gethostbyname)
 if test $ac_cv_func_gethostbyname = no; then
     AC_CHECK_LIB(nsl, gethostbyname)
@@ -578,7 +579,8 @@
 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 dnl
 EXTRA_DEFS=""
-if test "$MINGW32" = "yes" ; then
+case $host in
+  *-*-mingw*)
     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
       [Define if you have the <winsock2.h> header file.])])
     AC_CHECK_LIB(ws2_32, main)
@@ -592,7 +594,8 @@
       AC_DEFINE(USE_DLL_IMPORT, 1,
         [Define if you need additional CPP macros on Win32 platforms.])
     fi
-fi
+    ;;
+esac
 AC_SUBST(EXTRA_DEFS)
 
 # Reasons for testing:
@@ -798,7 +801,7 @@
                   #if HAVE_STDINT_H
                   #include <stdint.h>
                    #endif
-                  #ifndef __MINGW32__
+                  #ifndef HAVE_NETDB_H
                   #include <netdb.h>
                   #endif],
                  [uint32_t a;],