emacs-devel
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

alternate makefile variable constructs


From: Thien-Thi Nguyen
Subject: alternate makefile variable constructs
Date: Wed, 26 Mar 2003 08:45:49 +0100

folks,

as alluded in previous blurbs, i'm doing a vms port of emacs 21.  in
src/Makefile.in, i have had success avoiding the cpp-inserting-spaces
problem (openvms 7.3-1) by using this form of variable substitution:

 #ifdef VMS
 /* #define VMS_SUPPORT ${lispsource}vmsproc.elc ${lispsource}vms-patch.elc */
 VMS_SUPPORT = ${lispsource}vmsproc.elc ${lispsource}vms-patch.elc
 #else
 /* #define VMS_SUPPORT */
 VMS_SUPPORT =
 #endif

that is, instead of using #define, use actual makefile variables.  the
requisite change in var `lisp' is correspondingly:

 -      VMS_SUPPORT \
 +      $(VMS_SUPPORT) \

it seems to me for variables not user-settable (such as this one), the
#define approach does not bring any added benefit.  i welcome insight,
however.  in any case, cpp programs that insert spaces around "." lose
for these instances:

9 lines matching "^#define.*[.]" in buffer: Makefile.in
    230:#define START_FILES pre-crt0.o /usr/local/lib/gcc-crt0.o
    232:#define START_FILES pre-crt0.o /lib/crt0.o
    235:#define START_FILES ecrt0.o
    490:#define YMF_PASS_LDFLAGS(flags) `./prefix-args -Xlinker flags`
    544:#define UNEXEC unexec.o
    547:#define UNEXEC_SRC unexec.c
    647:#define MOUSE_SUPPORT ${lispsource}mouse.elc \
    662:#define MSDOS_SUPPORT ${lispsource}ls-lisp.elc 
${lispsource}disp-table.elc \
    671:#define WINNT_SUPPORT ${lispsource}ls-lisp.elc 
${lispsource}disp-table.elc \

(note: VMS_SUPPORT missing due to local change.)  generalizing from the
limited success, i propose we convert this small set of variables and
their references from #define style to makefile style.

alternatively, under vms i can kludge some TPU to do adhoc fixups, but i
would prefer not to have to go that route.  (i've already gone and done
horrible things on the front end, as you may be able to surmise from
work-in-progress make-mms-derivative.el below -- email me for an example
2mms file.)

thi


_________________________________________________
;;; make-mms-derivative.el --- framework to do horrible things for VMS support

;; Copyright (C) 2003 Free Software Foundation, Inc.

;; Author: Thien-Thi Nguyen <address@hidden>
;; Keywords: maint build vms mms makefile levitte autoconf war-is-a-lose
;; Favorite-TV-Game-Show: L'Eredità

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Under OpenVMS the standard make-like program is called MMS, which
;; looks for an input file in the default directory named DESCRIP.MMS
;; and runs the DCL command rules therein.  As of 2003, the build
;; process requires a hand translation of the Makefile.in and related
;; Emacs-specific methodology to DCL and TPU commands, so to alleviate
;; this pain, we provide `make-mms-derivative', which given a source
;; FILENAME (under `make-mms-derivative-root-dir'), inserts the file
;; contents in a new buffer and loads FILENAME.2mms.  The elisp in the
;; .2mms file can (do whatever -- it's emacs -- and) arrange to write
;; out the modified buffer after FILENAME.2mms loading by using:
;;
;;  (make-mms-derivative-data 'write-under-root RELATIVE-FILENAME)
;;
;; where RELATIVE-FILENAME is something like "src/descrip.mms_in_in".
;; Over the long run, the convenience procedures provided (see source)
;; will be augmented by factoring maximally the .2mms files, squeezing
;; as much algorithm out of those nasty heuristics as possible.  What
;; makes them nasty is not that they rely on the conventions of the
;; Emacs makefiles; that's no big deal.  What makes them nasty is that
;; they rely on the conventions of separately maintained tools (namely
;; Autoconf 1.11 under OpenVMS and the rest of GNU), and the separation
;; of conventions is how people drift apart, dragging their software
;; behind mercilessly.
;;
;; In general, codified thought w/o self-synchronization is doomed.
;; That a generation would eat its young (most discriminatingly, even)
;; is no reason GNU cannot build around such woe.

;;; Code:

(defvar make-mms-derivative-root-dir "~/build/GNU/emacs"
  "Source tree root directory.")

(defvar make-mms-derivative-data nil
  "Alist of data specific to `make-mms-derivative'.")

(defun make-mms-derivative-data (key &optional newval)
  (if newval
      (setq make-mms-derivative-data
            (cons (cons key newval) make-mms-derivative-data))
    (cdr (assq key make-mms-derivative-data))))

(defun make-mms-derivative-write-under-root (rel-filename)
  (write-file (expand-file-name rel-filename make-mms-derivative-root-dir)))

(defmacro make-mms-derivative-progn (msg &rest body)
  `(progn
     (message "(%s) %s" (point) ,msg)
     ,@body))

(put 'make-mms-derivative-progn 'lisp-indent-function 1)

(defun make-mms-derivative-load-edits-file (name)
  (make-mms-derivative-data 'edits-filename name)
  (let ((i 0) tmp res)
    (while (progn
             (setq tmp
                   (shell-command-to-string
                    (format "grep '^;;;%s;;' %s | sed 's/^;;;[0-9][0-9]*;;//g'"
                            i name)))
             (not (string= "" tmp)))
      (setq res (cons (cons i tmp) res)
            i (1+ i)))
    (make-mms-derivative-data 'raw-data res))
  (load name))

(defun make-mms-derivative-insert-raw-data (n)
  (insert (cdr (assq n (make-mms-derivative-data 'raw-data)))))

(defun make-mms-derivative (file)
  (interactive "fSource File: ")
  (let ((root (expand-file-name make-mms-derivative-root-dir))
        (file (expand-file-name file)))
    (unless (string-match (concat "^" root) file)
      (error "Not under root (%s)" root))
    (let ((edits-filename (concat file ".2mms")))
      (unless (file-exists-p edits-filename)
        (error "Could not find %s" edits-filename))
      (let* ((pre (+ (length root) (if (string= "/" (substring root -1)) 0 1)))
             (buf (get-buffer-create (format "*mms-derivative: %s"
                                             (substring file pre)))))
        (message "Munging ...")
        (switch-to-buffer buf)
        (erase-buffer)
        (make-variable-buffer-local 'make-mms-derivative-data)
        (insert-file file)
        (make-mms-derivative-load-edits-file edits-filename)
        (let ((out (make-mms-derivative-data 'write-under-root)))
          (when out (make-mms-derivative-write-under-root out))
          (kill-buffer buf)
          (unless out (message "Munging ... done")))))))

(provide 'make-mms-derivative)

;;; make-mms-derivative.el ends here




reply via email to

[Prev in Thread] Current Thread [Next in Thread]