Re: address@hidden: grep-tree doesn't shell-quote-argument]

[Kim F. Storm]

I took another round of cleaning up the grep.el module, fixing a
number of minor defects (not related to the issue of the new API).

Repeating myself (do I hear an echo?) many of the changes I've made
to grep.el should still be included in the release even if we decide
not to change the interactive api of grep and grep-find.

This time, I have included the entire grep.el below, as it turns out
that the file is 702 lines long, and a diff is also 702 lines long.


Please remember that the issue that started this was that users
complained about having two versions of "grep-find", and a request
to merge the "grep-tree" and "grep-find" APIs.  Then it became
clear that changing grep-find to have the "easy" API by default
meant that we should change grep in a similar way for consistency.

With the changes below, I have accomodated those requests.

IMO, it is a very good shape now, so if people would try it out for a
few days before making a final decision on the subject of a new API, I
would appreciate it -- after all, it is easier for me to just install
this (the IMHO "RIGHT" version), rather than having to backport the
necessary changes into grep-tree in the current CVS version.



;;; grep.el --- run Grep as inferior of Emacs, parse match messages

;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
;;   2001, 2002, 2003, 2004, 2005, 2006  Free Software Foundation, Inc.

;; Author: Roland McGrath <address@hidden>
;; Maintainer: FSF
;; Keywords: tools, processes

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; This package provides the grep facilities documented in the Emacs
;; user's manual.

;;; Code:

(require 'compile)


(defgroup grep nil
  "Run grep as inferior of Emacs, parse error messages."
  :group 'tools
  :group 'processes)


;;;###autoload
(defcustom grep-window-height nil
  "*Number of lines in a grep window.  If nil, use `compilation-window-height'."
  :type '(choice (const :tag "Default" nil)
                 integer)
  :version "22.1"
  :group 'grep)

(defcustom grep-highlight-matches 'auto-detect
  "If t, use special markers to highlight grep matches.

Some grep programs are able to surround matches with special
markers in grep output.  Such markers can be used to highlight
matches in grep mode.

This option sets the environment variable GREP_COLOR to specify
markers for highlighting and GREP_OPTIONS to add the --color
option in front of any explicit grep options before starting
the grep.

The default value of this variable is set up by `grep-compute-defaults';
call that function before using this variable in your program."
  :type '(choice (const :tag "Do not highlight matches with grep markers" nil)
                 (const :tag "Highlight matches with grep markers" t)
                 (other :tag "Not Set" auto-detect))
  :version "22.1"
  :group 'grep)

(defcustom grep-scroll-output nil
  "*Non-nil to scroll the *grep* buffer window as output appears.

Setting it causes the grep commands to put point at the end of their
output window so that the end of the output is always visible rather
than the begining."
  :type 'boolean
  :version "22.1"
  :group 'grep)

;;;###autoload
(defcustom grep-command nil
  "The default grep command for \\[grep].
If the grep program used supports an option to always include file names
in its output (such as the `-H' option to GNU grep), it's a good idea to
include it when specifying `grep-command'.

The default value of this variable is set up by `grep-compute-defaults';
call that function before using this variable in your program."
  :type '(choice string
                 (const :tag "Not Set" nil))
  :group 'grep)

(defcustom grep-command-template nil
  "The default find command for \\[grep-find].
The default value of this variable is set up by `grep-compute-defaults';
call that function before using this variable in your program.
The following place holders should be present in the string:
 <C> - place to put -i if case insensitive grep.
 <F> - file names and wildcards to search.
 <R> - the regular expression searched for."
  :type '(choice string
                 (const :tag "Not Set" nil))
  :version "22.1"
  :group 'grep)

(defcustom grep-use-null-device 'auto-detect
  "If t, append the value of `null-device' to `grep' commands.
This is done to ensure that the output of grep includes the filename of
any match in the case where only a single file is searched, and is not
necessary if the grep program used supports the `-H' option.

The default value of this variable is set up by `grep-compute-defaults';
call that function before using this variable in your program."
  :type '(choice (const :tag "Do Not Append Null Device" nil)
                 (const :tag "Append Null Device" t)
                 (other :tag "Not Set" auto-detect))
  :group 'grep)

;;;###autoload
(defcustom grep-find-command nil
  "The default find command for \\[grep-find].
The default value of this variable is set up by `grep-compute-defaults';
call that function before using this variable in your program."
  :type '(choice string
                 (const :tag "Not Set" nil))
  :group 'grep)

(defcustom grep-find-command-template nil
  "The default find command for \\[grep-find].
The default value of this variable is set up by `grep-compute-defaults';
call that function before using this variable in your program.
The following place holders should be present in the string:
 <D> - base directory for find
 <X> - find options to restrict or expand the directory list
 <F> - find options to limit the files matched
 <C> - place to put -i if case insensitive grep
 <R> - the regular expression searched for."
  :type '(choice string
                 (const :tag "Not Set" nil))
  :version "22.1"
  :group 'grep)

(defcustom grep-prompt-style nil
  "*Prompt style used by `grep' and `grep-find'.
Nil means to prompt for regexp, files, and directory.
Value `shell' means to prompt for shell command instead.
Value `post' means to post-edit the final shell command."
  :type '(choice (const :tag "Standard" nil)
                 (const :tag "Shell Command" shell)
                 (const :tag "Post-edit Command" post))
  :version "22.1"
  :group 'grep)

(defcustom grep-files-aliases '(
        ("el" . "*.el")
        ("ch" . "*.[ch]")
        ("c" .  "*.c")
        ("h" .  "*.h")
        ("asm" . "*.[sS]")
        ("m" .  "[Mm]akefile*")
        ("l" . "[Cc]hange[Ll]og*")
        )
  "*Alist of aliases for the FILES argument to `grep' and `grep-find'."
  :type 'alist
  :group 'grep)

(defcustom grep-find-ignored-directories '("CVS" ".hg" "{arch}")
  "*List of names of sub-directories which `grep-find' shall not recurse into."
  :type '(repeat string)
  :group 'grep)

(defcustom grep-error-screen-columns nil
  "*If non-nil, column numbers in grep hits are screen columns.
See `compilation-error-screen-columns'"
  :type '(choice (const :tag "Default" nil)
                 integer)
  :version "22.1"
  :group 'grep)

;;;###autoload
(defcustom grep-setup-hook nil
  "List of hook functions run by `grep-process-setup' (see `run-hooks')."
  :type 'hook
  :group 'grep)

(defvar grep-mode-map
  (let ((map (cons 'keymap compilation-minor-mode-map)))
    (define-key map " " 'scroll-up)
    (define-key map "\^?" 'scroll-down)
    (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)

    (define-key map "\r" 'compile-goto-error)  ;; ?
    (define-key map "n" 'next-error-no-select)
    (define-key map "p" 'previous-error-no-select)
    (define-key map "{" 'compilation-previous-file)
    (define-key map "}" 'compilation-next-file)
    (define-key map "\t" 'compilation-next-error)
    (define-key map [backtab] 'compilation-previous-error)

    ;; Set up the menu-bar
    (define-key map [menu-bar grep]
      (cons "Grep" (make-sparse-keymap "Grep")))

    (define-key map [menu-bar grep compilation-kill-compilation]
      '("Kill Grep" . kill-compilation))
    (define-key map [menu-bar grep compilation-separator2]
      '("----" . nil))
    (define-key map [menu-bar grep compilation-compile]
      '("Compile..." . compile))
    (define-key map [menu-bar grep compilation-grep]
      '("Another grep..." . grep))
    (define-key map [menu-bar grep compilation-grep-find]
      '("Recursive grep..." . grep-find))
    (define-key map [menu-bar grep compilation-recompile]
      '("Repeat grep" . recompile))
    (define-key map [menu-bar grep compilation-separator2]
      '("----" . nil))
    (define-key map [menu-bar grep compilation-first-error]
      '("First Match" . first-error))
    (define-key map [menu-bar grep compilation-previous-error]
      '("Previous Match" . previous-error))
    (define-key map [menu-bar grep compilation-next-error]
      '("Next Match" . next-error))
    map)
  "Keymap for grep buffers.
`compilation-minor-mode-map' is a cdr of this.")

(defalias 'kill-grep 'kill-compilation)

;;;; TODO --- refine this!!

;;; (defcustom grep-use-compilation-buffer t
;;;   "When non-nil, grep specific commands update `compilation-last-buffer'.
;;; This means that standard compile commands like \\[next-error] and 
\\[compile-goto-error]
;;; can be used to navigate between grep matches (the default).
;;; Otherwise, the grep specific commands like \\[grep-next-match] must
;;; be used to navigate between grep matches."
;;;   :type 'boolean
;;;   :group 'grep)

;; override compilation-last-buffer
(defvar grep-last-buffer nil
  "The most recent grep buffer.
A grep buffer becomes most recent when its process is started
or when it is used with \\[grep-next-match].
Notice that using \\[next-error] or \\[compile-goto-error] modifies
`complation-last-buffer' rather than `grep-last-buffer'.")

;;;###autoload
(defvar grep-regexp-alist
  '(("^\\(.+?\\)\\(:[ \t]*\\)\\([0-9]+\\)\\2"
     1 3)
    ;; Rule to match column numbers is commented out since no known grep
    ;; produces them
    ;; ("^\\(.+?\\)\\(:[ 
\t]*\\)\\([0-9]+\\)\\2\\(?:\\([0-9]+\\)\\(?:-\\([0-9]+\\)\\)?\\2\\)?"
    ;;  1 3 (4 . 5))
    ("^\\(\\(.+?\\):\\([0-9]+\\):\\).*?\
\\(\033\\[01;31m\\(?:\033\\[K\\)?\\)\\(.*?\\)\\(\033\\[[0-9]*m\\)"
     2 3
     ;; Calculate column positions (beg . end) of first grep match on a line
     ((lambda ()
        (setq compilation-error-screen-columns nil)
        (- (match-beginning 4) (match-end 1)))
      .
      (lambda () (- (match-end 5) (match-end 1)
                    (- (match-end 4) (match-beginning 4)))))
     nil 1)
    ("^Binary file \\(.+\\) matches$" 1 nil nil 0 1))
  "Regexp used to match grep hits.  See `compilation-error-regexp-alist'.")

(defvar grep-error "grep hit"
  "Message to print when no matches are found.")

;; Reverse the colors because grep hits are not errors (though we jump there
;; with `next-error'), and unreadable files can't be gone to.
(defvar grep-hit-face   compilation-info-face
  "Face name to use for grep hits.")

(defvar grep-error-face 'compilation-error
  "Face name to use for grep error messages.")

(defvar grep-match-face 'match
  "Face name to use for grep matches.")

(defvar grep-context-face 'shadow
  "Face name to use for grep context lines.")

(defvar grep-mode-font-lock-keywords
   '(;; Command output lines.
     ("^\\([A-Za-z_0-9/\.+-]+\\)[ \t]*:" 1 font-lock-function-name-face)
     (": \\(.+\\): \\(?:Permission denied\\|No such \\(?:file or 
directory\\|device or address\\)\\)$"
      1 grep-error-face)
     ;; remove match from grep-regexp-alist before fontifying
     ("^Grep started.*"
      (0 '(face nil message nil help-echo nil mouse-face nil) t))
     ("^Grep finished \\(?:(\\(matches found\\))\\|with \\(no matches 
found\\)\\).*"
      (0 '(face nil message nil help-echo nil mouse-face nil) t)
      (1 compilation-info-face nil t)
      (2 compilation-warning-face nil t))
     ("^Grep \\(exited 
abnormally\\|interrupt\\|killed\\|terminated\\)\\(?:.*with code 
\\([0-9]+\\)\\)?.*"
      (0 '(face nil message nil help-echo nil mouse-face nil) t)
      (1 grep-error-face)
      (2 grep-error-face nil t))
     ("^.+?-[0-9]+-.*\n" (0 grep-context-face))
     ;; Highlight grep matches and delete markers
     ("\\(\033\\[01;31m\\)\\(.*?\\)\\(\033\\[[0-9]*m\\)"
      ;; Refontification does not work after the markers have been
      ;; deleted.  So we use the font-lock-face property here as Font
      ;; Lock does not clear that.
      (2 (list 'face nil 'font-lock-face grep-match-face))
      ((lambda (bound))
       (progn
         ;; Delete markers with `replace-match' because it updates
         ;; the match-data, whereas `delete-region' would render it obsolete.
         (replace-match "" t t nil 3)
         (replace-match "" t t nil 1))))
     ("\\(\033\\[[0-9;]*[mK]\\)"
      ;; Delete all remaining escape sequences
      ((lambda (bound))
       (replace-match "" t t nil 1))))
   "Additional things to highlight in grep output.
This gets tacked on the end of the generated expressions.")

;;;###autoload
(defvar grep-program
  ;; Currently zgrep has trouble.  It runs egrep instead of grep,
  ;; and it doesn't pass along long options right.
  "grep"
  ;; (if (equal (condition-case nil     ; in case "zgrep" isn't in exec-path
  ;;             (call-process "zgrep" nil nil nil
  ;;                           "foo" null-device)
  ;;           (error nil))
  ;;         1)
  ;;     "zgrep"
  ;;   "grep")
  "The default grep program for `grep-command' and `grep-find-command'.
This variable's value takes effect when `grep-compute-defaults' is called.")

;;;###autoload
(defvar find-program "find"
  "The default find program for `grep-find-command'.
This variable's value takes effect when `grep-compute-defaults' is called.")

;;;###autoload
(defvar grep-find-use-xargs nil
  "Whether \\[grep-find] uses the `xargs' utility by default.

If nil, it uses `find -exec'; if `gnu', it uses `find -print0' and `xargs -0';
if not nil and not `gnu', it uses `find -print' and `xargs'.

This variable's value takes effect when `grep-compute-defaults' is called.")

;; History of grep commands.
;;;###autoload
(defvar grep-history nil)
;;;###autoload
(defvar grep-find-history nil)

;; History of grep and grep-find regexp and files args.
(defvar grep-regexp-history nil)
(defvar grep-files-history '("ch" "el"))


;;;###autoload
(defun grep-process-setup ()
  "Setup compilation variables and buffer for `grep'.
Set up `compilation-exit-message-function' and run `grep-setup-hook'."
  (unless (or (not grep-highlight-matches) (eq grep-highlight-matches t))
    (grep-compute-defaults))
  (when (eq grep-highlight-matches t)
    ;; Modify `process-environment' locally bound in `compilation-start'
    (setenv "GREP_OPTIONS" (concat (getenv "GREP_OPTIONS") " --color=always"))
    ;; for GNU grep 2.5.1
    (setenv "GREP_COLOR" "01;31")
    ;; for GNU grep 2.5.1-cvs
    (setenv "GREP_COLORS" "mt=01;31:fn=:ln=:bn=:se=:ml=:cx=:ne"))
  (set (make-local-variable 'compilation-exit-message-function)
       (lambda (status code msg)
         (if (eq status 'exit)
             (cond ((zerop code)
                    '("finished (matches found)\n" . "matched"))
                   ((= code 1)
                    '("finished with no matches found\n" . "no match"))
                   (t
                    (cons msg code)))
           (cons msg code))))
  (run-hooks 'grep-setup-hook))

;;;###autoload
(defun grep-compute-defaults ()
  (unless (or (not grep-use-null-device) (eq grep-use-null-device t))
    (setq grep-use-null-device
          (with-temp-buffer
            (let ((hello-file (expand-file-name "HELLO" data-directory)))
              (not
               (and (equal (condition-case nil
                               (if grep-command
                                   ;; `grep-command' is already set, so
                                   ;; use that for testing.
                                   (call-process-shell-command
                                    grep-command nil t nil
                                    "^English" hello-file)
                                 ;; otherwise use `grep-program'
                                 (call-process grep-program nil t nil
                                               "-nH" "^English" hello-file))
                             (error nil))
                           0)
                    (progn
                      (goto-char (point-min))
                      (looking-at
                       (concat (regexp-quote hello-file)
                               ":[0-9]+:English")))))))))
  (unless (and grep-command grep-command-template
               grep-find-command grep-find-command-template)
    (let ((required-options
           (concat (if grep-use-null-device "-n" "-nH")
                   (if (equal (condition-case nil ; in case "grep" isn't in 
exec-path
                                  (call-process grep-program nil nil nil
                                                "-e" "foo" null-device)
                                (error nil))
                              1) " -e" ""))))
      (unless grep-command
        (setq grep-command
              (format "%s %s " grep-program required-options)))
      (unless grep-command-template
        (setq grep-command-template
              (format "%s <C> %s <R> <F>" grep-program required-options)))
      (unless grep-find-use-xargs
        (setq grep-find-use-xargs
              (if (and
                   (equal (call-process "find" nil nil nil
                                        null-device "-print0")
                          0)
                   (equal (call-process "xargs" nil nil nil
                                        "-0" "-e" "echo")
                          0))
                  'gnu)))
      (unless grep-find-command
        (setq grep-find-command
              (cond ((eq grep-find-use-xargs 'gnu)
                     (format "%s . -type f -print0 | xargs -0 -e %s"
                             find-program grep-command))
                    (grep-find-use-xargs
                     (format "%s . -type f -print | xargs %s"
                             find-program grep-command))
                    (t (cons (format "%s . -type f -exec %s {} %s \\;"
                                     find-program grep-command null-device)
                             (+ 22 (length grep-command)))))))
      (unless grep-find-command-template
        (setq grep-find-command-template
              (let ((gcmd (format "%s <C> %s <R>"
                                  grep-program required-options)))
                (cond ((eq grep-find-use-xargs 'gnu)
                       (format "%s <D> <X> -type f <F> -print0 | xargs -0 -e %s"
                               find-program gcmd))
                      (grep-find-use-xargs
                       (format "%s <D> <X> -type f <F> -print | xargs %s"
                               find-program gcmd))
                      (t (format "%s <D> <X> -type f <F> -exec %s {} %s \\;"
                                 find-program gcmd null-device))))))
      (unless (or (not grep-highlight-matches) (eq grep-highlight-matches t))
        (setq grep-highlight-matches
              (with-temp-buffer
                (and (equal (condition-case nil
                                (call-process grep-program nil t nil "--help")
                              (error nil))
                            0)
                     (progn
                       (goto-char (point-min))
                       (search-forward "--color" nil t))
                     t)))))))

(defun grep-expand-template (template &optional regexp files dir excl)
  "Patch grep COMMAND string replacing <C>, <D>, <F>, <R>, and <X>."
  (let ((command template)
        (case-fold case-fold-search)
        (case-fold-search nil))
    (if (string-match "<C>" command)
        (setq command
              (replace-match (if (and case-fold
                                      (isearch-no-upper-case-p regexp t))
                                 "-i" "")
                             t t command)))
    (if (string-match "<D>" command)
        (setq command
              (replace-match (or dir ".")
                             t t command)))
    (if (string-match "<F>" command)
        (setq command
              (replace-match (or files "")
                             t t command)))
    (if (string-match "<N>" command)
        (setq command
              (replace-match (if (and grep-use-null-device null-device)
                                 null-device "")
                             t t command)))
    (if (string-match "<X>" command)
        (setq command
          (replace-match (or excl "")
                         t t command)))
    (if (string-match "<R>" command)
        (setq command
              (replace-match (shell-quote-argument (or regexp ""))
                             t t command)))
    command))

(defun grep-read-regexp ()
  "Read regexp arg for interactive grep."
  (let ((default
          (or (funcall (or find-tag-default-function
                           (get major-mode 'find-tag-default-function)
                           'find-tag-default))
              "")))
    (read-string
     (concat "Search for"
             (if (and default (> (length default) 0))
                 (format " (default %s): " default) ": "))
     nil 'grep-regexp-history default)))

(defun grep-read-files (regexp)
  "Read files arg for interactive grep."
  (let* ((default
           (or (and (stringp (buffer-file-name))
                    (let ((fn (file-name-nondirectory (buffer-file-name)))
                          (aliases grep-files-aliases)
                          alias)
                      (while aliases
                        (setq alias (car aliases)
                              aliases (cdr aliases))
                        (if (string-match (wildcard-to-regexp (cdr alias)) fn)
                            (setq aliases nil)
                          (setq alias nil)))
                      (cdr alias)))
               (car grep-files-history)))
         (files (read-string
                 (concat "Search for \"" regexp
                         "\" in files (default " default "): ")
                 nil 'grep-files-history default)))
    (and files
         (or (cdr (assoc files grep-files-aliases))
             files))))

;;;###autoload
(defun grep (regexp &optional files)
  "Run grep, searching for REGEXP in FILES in current directory.
Collect output in a buffer.
Interactively, prompt separately for each search parameter.
The search is limited to file names matching shell pattern FILES.
FILES may use abbreviations defined in `grep-files-aliases', e.g.
entering `ch' is equivalent to `*.[ch]'.

With \\[universal-argument] prefix, prompt for shell command instead.
With two \\[universal-argument] prefixes, prompt for search parameters,
and allow user to edit the final shell command before it is submitted.
Note that setting `grep-prompt-style' overrides any prefix arg.

While grep runs asynchronously, you can use \\[next-error] (M-x next-error),
or \\<grep-mode-map>\\[compile-goto-error] in the grep \
output buffer, to go to the lines
where grep found matches.

This command uses a special history list for its arguments, so you can
easily repeat a grep command."
  (interactive
   (progn
     (grep-compute-defaults)
     (cond
      ((or (eq grep-prompt-style 'shell)
           (equal current-prefix-arg '(4)))
       (if grep-command
           (list (read-from-minibuffer "Run grep (like this): "
                                       grep-command nil nil
                                       'grep-history)
                 nil)
         ;; No default was set
         (read-string
          "grep.el: No `grep-command' available. Press RET.")
         (list nil nil)))
      ((not grep-command-template)
       (read-string
        "grep.el: No `grep-command-template' available. Press RET.")
       (list nil nil))
      (t
       (let* ((regexp (grep-read-regexp))
              (files (grep-read-files regexp)))
         (list regexp files))))))
  (when regexp
    (let (command)
      (if (or (null files)  ;; C-u or backwards compatible non-interactive call
              (eq grep-prompt-style 'shell))
          (setq command regexp)
        (setq command (grep-expand-template
                       grep-command-template
                       regexp
                       files))
        (when command
          (if (or (eq grep-prompt-style 'post)
                  (equal current-prefix-arg '(16)))
              (setq command
                    (read-from-minibuffer "Confirm: "
                                          command nil nil 'grep-find-history))
            (push command grep-history))))
      (when command
        ;; Setting process-setup-function makes exit-message-function work
        ;; even when async processes aren't supported.
        (compilation-start (if (and grep-use-null-device null-device)
                               (concat command " " null-device)
                             command) 'grep-mode)))))

;;;###autoload
(define-compilation-mode grep-mode "Grep"
  "Sets `grep-last-buffer' and `compilation-window-height'."
  (setq grep-last-buffer (current-buffer))
  (set (make-local-variable 'compilation-error-face)
       grep-hit-face)
  (set (make-local-variable 'compilation-error-regexp-alist)
       grep-regexp-alist)
  (set (make-local-variable 'compilation-process-setup-function)
       'grep-process-setup)
  (set (make-local-variable 'compilation-disable-input) t))

;;;###autoload
(defun grep-find (regexp &optional files dir api)
  "Recusively grep for REGEXP in FILES in directory tree rooted at DIR.
Collect output in a buffer.
Interactively, prompt separately for each search parameter.
The search is limited to file names matching shell pattern FILES.
FILES may use abbreviations defined in `grep-files-aliases', e.g.
entering `ch' is equivalent to `*.[ch]'.

With \\[universal-argument] prefix, prompt for shell command instead.
With two \\[universal-argument] prefixes, prompt for search parameters,
and allow user to edit the final shell command before it is submitted.
Note that setting `grep-prompt-style' overrides any prefix arg.

While find runs asynchronously, you can use the \\[next-error] command
to find the text that grep hits refer to.

This command uses a special history list for its arguments, so you can
easily modify or repeat a find command."
  (interactive
   (progn
     (grep-compute-defaults)
     (cond
      ((or (eq grep-prompt-style 'shell)
           (equal current-prefix-arg '(4)))
       (if grep-find-command
           (list (read-from-minibuffer "Run find (like this): "
                                       grep-find-command nil nil
                                       'grep-find-history)
                 nil nil)

         ;; No default was set
         (read-string
          "grep.el: No `grep-find-command' available. Press RET.")
         (list nil nil nil)))
      ((not grep-find-command-template)
       (read-string
        "grep.el: No `grep-find-command-template' available. Press RET.")
       (list nil nil nil))
      (t
       (let* ((regexp (grep-read-regexp))
              (files (grep-read-files regexp))
              (dir (read-directory-name "Base directory: "
                                        nil default-directory t)))
         (list regexp files dir))))))
  (when regexp
    (if (or (null files)  ;; C-u or backwards compatible non-interactive call
            (eq grep-prompt-style 'shell))
        ;; REGEXP is command line
        (compilation-start regexp 'grep-mode)
      (let ((command (grep-expand-template
                      grep-find-command-template
                      regexp
                      (and files (concat "-name "
                                         (shell-quote-argument files)))
                      nil  ;; we change default-directory to dir
                      (and grep-find-ignored-directories
                           (concat "\\( -path '*/"
                                   (mapconcat #'identity
                                              grep-find-ignored-directories
                                              "' -o -path '*/")
                                   "' \\) -prune -o "))))
            (default-directory (file-name-as-directory (expand-file-name dir))))
        (when command
          (if (or (eq grep-prompt-style 'post)
                  (equal current-prefix-arg '(16)))
              (setq command
                    (read-from-minibuffer "Confirm: "
                                          command nil nil 'grep-find-history))
            (push command grep-find-history))
          (compilation-start command 'grep-mode))))))

;;;###autoload
(defalias 'find-grep 'grep-find)

(provide 'grep)

;; arch-tag: 5a5b9169-a79d-4f38-9c38-f69615f39c4d
;;; grep.el ends here

-- 
Kim F. Storm <address@hidden> http://www.cua.dk