count-words-region

[Stephen Berman]

The newly installed count-words-region differs from the shell command wc
in certain cases, for example, in this sentence: "How many words does
count-words-region say this sentence has?"  I think wc delimits words by
white space.  This may sometimes be better than word syntax, but
sometimes worse (e.g. if a comment string like ";;" is counted).  It
could be useful to allow a command for counting words to be flexible
with respect to what delimits words.  Here's an implementation that does
this:

(defun count-words (&optional syntax)
  "Count words in region if it exists, else in visible buffer.
What counts as a word depends on the syntax class, solicited by
prefix argument SYNTAX; the default is to use white space to
delimit words, like the shell command wc."
  (interactive "P")
  (let ((syn (if syntax (read-from-minibuffer "Syntax code: ") " "))
        (beg (if (mark t) (region-beginning) (point-min)))
        (end (if (mark t) (region-end) (point-max)))
        (count 0))
    (save-excursion
      (goto-char beg)
      ;; don't count initial white space
      (and (string= syn " ") (skip-syntax-forward syn)) 
      (while (< (point) end)
        (skip-syntax-forward (concat "^" syn))
        (unless (>= (point) end) (skip-syntax-forward syn))
        (setq count (1+ count))))
    (message "%d words in %s"
             count (if (> (buffer-size) (- end beg)) "region" "buffer"))))

Steve Berman