[PATCH] improve mpc seeking

[Mark Oteiza]

Hi,

The following adds to the mpc-seek-current command.
It's pretty loose regexp, i.e. you can do things like

  +1:2.3:200 (seek forward 1 hour + 2.3 minutes + 200 seconds)

and there is the issue of string-to-number returning 0 on failure...
but is otherwise convenient:

  -1:: (seek back one hour)
  123 (go to 123 seconds)
  +2:30 (seek forward 2 mins, 30 seconds)

I'm not sure if I'm NIHing something from somewhere else in Emacs,
however.

diff --git a/lisp/mpc.el b/lisp/mpc.el
index c23d8ced71..98f4a03183 100644
--- a/lisp/mpc.el
+++ b/lisp/mpc.el
@@ -2403,10 +2403,38 @@ mpc-resume
   (interactive)
   (mpc-cmd-pause "0"))
 
+(defun mpc-read-seek (prompt)
+  "Read a seek time.
+Returns a string suitable for MPD \"seekcur\" protocol command."
+  (let* ((str (read-from-minibuffer prompt nil nil nil nil nil t))
+         (seconds "\\(?1:[[:digit:]]+\\(?:\\.[[:digit:]]*\\)?\\)")
+         (minsec (concat "\\(?2:[[:digit:]]+\\):" seconds "?"))
+         (hrminsec (concat "\\(?3:[[:digit:]]+\\):\\(?:" minsec "?\\|:\\)"))
+         time sign)
+    (setq str (string-trim str))
+    (when (memq (string-to-char str) '(?+ ?-))
+      (setq sign (string (string-to-char str)))
+      (setq str (substring str 1)))
+    (setq time
+          ;; `string-to-number' returns 0 on failure
+          (cond
+           ((string-match (concat "^" hrminsec "$") str)
+            (+ (* 3600 (string-to-number (match-string 3 str)))
+               (* 60 (string-to-number (or (match-string 2 str) "")))
+               (string-to-number (or (match-string 1 str) ""))))
+           ((string-match (concat "^" minsec "$") str)
+            (+ (* 60 (string-to-number (match-string 2 str)))
+               (string-to-number (match-string 1 str))))
+           ((string-match (concat "^" seconds "$") str)
+            (string-to-number (match-string 1 str)))
+           (t (user-error "Invalid time"))))
+    (setq time (number-to-string time))
+    (if (null sign) time (concat sign time))))
+
 (defun mpc-seek-current (pos)
   "Seek within current track."
   (interactive
-   (list (read-string "Position to go ([+-]seconds): ")))
+   (list (mpc-read-seek "Position to go ([+-][[H:]M:]seconds): ")))
   (mpc-cmd-seekcur pos))
 
 (defun mpc-toggle-play ()