[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: [O] formatting org-babel output
From: |
Eric Schulte |
Subject: |
Re: [O] formatting org-babel output |
Date: |
Wed, 22 May 2013 07:12:41 -0600 |
User-agent: |
Gnus/5.13 (Gnus v5.13) Emacs/24.3 (gnu/linux) |
Joe Bogner <address@hidden> writes:
> I am using org-mode and babel with R for reproducible research. I
> would like certain numbers in the output tables to be formatted for
> easier reading - such as eliminating decimals and adding commas for
> readability.
>
> The best I came up with is to use a TBLFM line at the bottom of my
> results table using a function I found on the ElispCookbook on
> emacswiki. A simple example is below that doesn't require R to
> reproduce.
>
> It's a two step process currently to execute the R code in org-babel
> and then jump to the result table TBLFM line and Ctrl+c Ctrl+c to
> format the table
>
> Is there a better way to format table outputs for simple things like
> currency? I would be content if it's only during the org export
> process too
>
You can use the recently introduced :post header argument to
post-process the output of a code block. The following example
demonstrates the use of this argument to apply your number-grouper
function to table output.
#+BEGIN_SRC emacs-lisp :results silent
(defun group-number (num &optional size char)
"Format NUM as string grouped to SIZE with CHAR."
;; Based on code for `math-group-float' in calc-ext.el
(let* ((size (or size 3))
(char (or char ","))
(str (if (stringp num)
(number-to-string (string-to-number
(replace-regexp-in-string "," "" num)))
(number-to-string num)))
(pt (or (string-match "[^0-9a-zA-Z]" str) (length str))))
(while (> pt size)
(setq str (concat (substring str 0 (- pt size))
char
(substring str (- pt size)))
pt (- pt size)))
str))
#+END_SRC
The following code block will call the group-number Emacs Lisp
function on every cell in its input argument which is a number.
#+name: table-number-grouper
#+BEGIN_SRC emacs-lisp :var data='()
(mapcar (lambda (row)
(if (equalp row 'hline) 'hline
(mapcar (lambda (cell) (if (numberp cell) (group-number cell)
cell))
row)))
data)
#+END_SRC
Here's a simple shell code block which produces the table (this is a
stand in for your R code block).
#+begin_src sh
cat <<EOF
100000000.55 a
23000 b
3000 c
40004 e
5000 3
EOF
#+end_src
#+RESULTS:
| 100000000.55 | a |
| 23000 | b |
| 3000 | c |
| 40004 | e |
| 5000 | 3 |
Above is the poorly formatted output of your block. Below we add the
"post" header argument to your block, which will use the
"table-number-grouper" code block above to post-process your results.
#+begin_src sh :post table-number-grouper(*this*)
cat <<EOF
100000000.55 a
23000 b
3000 c
40004 e
5000 3
EOF
#+end_src
#+RESULTS:
| 100,000,000.55 | a |
| 23,000 | b |
| 3,000 | c |
| 40,004 | e |
| 5,000 | 3 |
Cheers,
--
Eric Schulte
http://cs.unm.edu/~eschulte