Re: How to set mode line to show full path of current file

[Kevin Rodgers]

On 1/18/11 12:05 PM, Ashwin Purohit wrote:
> I'd like to set the mode line to show the full path of the current file, but
> only to _replace_ the filename with the fullpath, instead of wiping the entire
> mode line and replacing it by just the filepath. There are other things, like
> line position and time that I would like to keep on the mode line.
>
> What I'm currently using:
> ;; set mode line to show full path of current file
> (setq-default mode-line-format
>     (list '((buffer-file-name " %f"
>                (dired-directory
>                 dired-directory
>                  (revert-buffer-function " %b"
>                 ("%b - Dir: " default-directory)))))))

(setq-default mode-line-buffer-identification
              (list 'buffer-file-name
                    (propertized-buffer-identification "%12f")
                    (propertized-buffer-identification "%12b")))

(add-hook 'dired-mode-hook
          (lambda ()
            ;; TODO: handle (DIRECTORY FILE ...) list value for dired-directory
            (setq mode-line-buffer-identification
                  ;; emulate "%17b" (see dired-mode):
                  '(:eval
                    (propertized-buffer-identification
                     (if (< (length default-directory) 17)
                         (concat default-directory
                                 (make-string (- 17 (length default-directory))
                                              ?\s))
                       default-directory))))))
--
Kevin Rodgers
Denver, Colorado, USA