Solving our bootstrap woes

[Scott James Remnant]

This isn't a patch, it's just a new file to drop in the distribution as
m4/lt~obsolete.m4.  Ok, it needs adding to EXTRA_DIST as well, but
that's it.

I think the comment I've put in it explains how it works pretty well,
basically instead of whatever you've got in
/usr/share/aclocal/libtool.m4 turning up in your aclocal.m4, you get
this instead; which is harmless because the filename is asciibetically
after anything else in m4/ so the m4_ifdef just expand to [].

Okay to commit?

Scott
-- 
Have you ever, ever felt like this?
Had strange things happen?  Are you going round the twist?

# lt~obsolete.m4 -- aclocal satisfying obsolete definitions.    -*-Autoconf-*-
# 
# Copyright (C) 2004 Free Software Foundation, Inc.
# Written by Scott James Remnant.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
#
# As a special exception to the GNU General Public License, if you
# distribute this file as part of a program that contains a
# configuration script generated by Autoconf, you may include it under
# the same distribution terms that you use for the rest of that program.

# serial 1

# These exist entirely to fool aclocal when bootstrapping libtool.
#
# In the past libtool.m4 has provided macros via AC_DEFUN (or AU_DEFUN)
# which have later been changed to m4_define as they aren't part of the
# exported API, or moved to Autoconf or Automake where they belong.
#
# The trouble is, aclocal is a bit thick.  It'll see the old AC_DEFUN
# in /usr/share/aclocal/libtool.m4 and remember it, then when it sees us
# using a macro with the same name in our local m4/libtool.m4 it'll
# pull the old libtool.m4 in (it doesn't see our shiny new m4_define
# and doesn't know about Autoconf macros at all.)
# 
# So we provide this file, which has a silly filename so it's always
# included after everything else.  This provides aclocal with the
# AU_DEFUNs it wants, but when m4 processes it, it doesn't do anything
# because those macros already exist.
# 
# Anytime we withdraw an AC_DEFUN or AU_DEFUN, but still refer to it,
# remember to add it here.

m4_ifdef([AC_LIBTOOL_CONFIG], [], [AU_DEFUN([AC_LIBTOOL_CONFIG])])dnl
m4_ifdef([AC_LIBTOOL_LINKER_OPTION], [], 
[AU_DEFUN([AC_LIBTOOL_LINKER_OPTION])])dnl
m4_ifdef([AC_PROG_EGREP], [], [AU_DEFUN([AC_PROG_EGREP])])dnl
m4_ifdef([_LT_AC_LANG_C_CONFIG], [], [AU_DEFUN([_LT_AC_LANG_C_CONFIG])])dnl
m4_ifdef([_LT_AC_LANG_GCJ_CONFIG], [], [AU_DEFUN([_LT_AC_LANG_GCJ_CONFIG])])dnl
m4_ifdef([_LT_AC_LANG_RC_CONFIG], [], [AU_DEFUN([_LT_AC_LANG_RC_CONFIG])])dnl
m4_ifdef([_LT_AC_PROG_ECHO_BACKSLASH], [], 
[AU_DEFUN([_LT_AC_PROG_ECHO_BACKSLASH])])dnl
m4_ifdef([_LT_AC_SHELL_INIT], [], [AU_DEFUN([_LT_AC_SHELL_INIT])])dnl
m4_ifdef([_LT_AC_SYS_LIBPATH_AIX], [], [AU_DEFUN([_LT_AC_SYS_LIBPATH_AIX])])dnl
m4_ifdef([_LT_AC_TAGVAR], [], [AU_DEFUN([_LT_AC_TAGVAR])])dnl

signature.asc
Description: This is a digitally signed message part