[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
trans-coord/gnun/server/gnun/m4-external ax_che...
From: |
Pavel Kharitonov |
Subject: |
trans-coord/gnun/server/gnun/m4-external ax_che... |
Date: |
Tue, 24 Jan 2017 10:45:34 -0500 (EST) |
CVSROOT: /sources/trans-coord
Module name: trans-coord
Changes by: Pavel Kharitonov <ineiev> 17/01/24 10:45:34
Added files:
gnun/server/gnun/m4-external: ax_check_awk_gsub.m4
ax_compare_version.m4
ax_need_awk.m4
ax_try_awk_expout.m4
check_gnu_make.m4
Log message:
Remove GNUN notice and move from ../m4.
CVSWeb URLs:
http://cvs.savannah.gnu.org/viewcvs/trans-coord/gnun/server/gnun/m4-external/ax_check_awk_gsub.m4?cvsroot=trans-coord&rev=1.1
http://cvs.savannah.gnu.org/viewcvs/trans-coord/gnun/server/gnun/m4-external/ax_compare_version.m4?cvsroot=trans-coord&rev=1.1
http://cvs.savannah.gnu.org/viewcvs/trans-coord/gnun/server/gnun/m4-external/ax_need_awk.m4?cvsroot=trans-coord&rev=1.1
http://cvs.savannah.gnu.org/viewcvs/trans-coord/gnun/server/gnun/m4-external/ax_try_awk_expout.m4?cvsroot=trans-coord&rev=1.1
http://cvs.savannah.gnu.org/viewcvs/trans-coord/gnun/server/gnun/m4-external/check_gnu_make.m4?cvsroot=trans-coord&rev=1.1
Patches:
Index: ax_check_awk_gsub.m4
===================================================================
RCS file: ax_check_awk_gsub.m4
diff -N ax_check_awk_gsub.m4
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ ax_check_awk_gsub.m4 24 Jan 2017 15:45:34 -0000 1.1
@@ -0,0 +1,36 @@
+# ===========================================================================
+# http://autoconf-archive.cryp.to/ax_check_awk_gsub.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# AX_CHECK_AWK_GSUB([ACTION-IF-SUCCESS],[ACTION-IF-FAILURE])
+#
+# DESCRIPTION
+#
+# Check if AWK supports gsub() function. If successful execute
+# ACTION-IF-SUCCESS otherwise ACTION-IF-FAILURE.
+#
+# This work is heavily based upon testawk.sh script by Heiner Steven. You
+# should find his script (and related works) at
+# <http://www.shelldorado.com/articles/awkcompat.html>. Thanks to
+# Alessandro Massignan for his suggestions and extensive nawk tests on
+# FreeBSD.
+#
+# LAST MODIFICATION
+#
+# 2008-04-12
+#
+# COPYLEFT
+#
+# Copyright (c) 2008 Francesco Salvestrini <address@hidden>
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved.
+
+AC_DEFUN([AX_CHECK_AWK_GSUB], [
+ AX_TRY_AWK_EXPOUT([gsub()],
+ [],[ s = "AB"; gsub(/./, "X", s); print s ],[XX],
+ [$1],[$2])
+])
Index: ax_compare_version.m4
===================================================================
RCS file: ax_compare_version.m4
diff -N ax_compare_version.m4
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ ax_compare_version.m4 24 Jan 2017 15:45:34 -0000 1.1
@@ -0,0 +1,174 @@
+# ===========================================================================
+# http://www.nongnu.org/autoconf-archive/ax_compare_version.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE],
[ACTION-IF-FALSE])
+#
+# DESCRIPTION
+#
+# This macro compares two version strings. Due to the various number of
+# minor-version numbers that can exist, and the fact that string
+# comparisons are not compatible with numeric comparisons, this is not
+# necessarily trivial to do in a autoconf script. This macro makes doing
+# these comparisons easy.
+#
+# The six basic comparisons are available, as well as checking equality
+# limited to a certain number of minor-version levels.
+#
+# The operator OP determines what type of comparison to do, and can be one
+# of:
+#
+# eq - equal (test A == B)
+# ne - not equal (test A != B)
+# le - less than or equal (test A <= B)
+# ge - greater than or equal (test A >= B)
+# lt - less than (test A < B)
+# gt - greater than (test A > B)
+#
+# Additionally, the eq and ne operator can have a number after it to limit
+# the test to that number of minor versions.
+#
+# eq0 - equal up to the length of the shorter version
+# ne0 - not equal up to the length of the shorter version
+# eqN - equal up to N sub-version levels
+# neN - not equal up to N sub-version levels
+#
+# When the condition is true, shell commands ACTION-IF-TRUE are run,
+# otherwise shell commands ACTION-IF-FALSE are run. The environment
+# variable 'ax_compare_version' is always set to either 'true' or 'false'
+# as well.
+#
+# Examples:
+#
+# AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
+# AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
+#
+# would both be true.
+#
+# AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
+# AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
+#
+# would both be false.
+#
+# AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
+#
+# would be true because it is only comparing two minor versions.
+#
+# AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
+#
+# would be true because it is only comparing the lesser number of minor
+# versions of the two values.
+#
+# Note: The characters that separate the version numbers do not matter. An
+# empty string is the same as version 0. OP is evaluated by autoconf, not
+# configure, so must be a string, not a variable.
+#
+# The author would like to acknowledge Guido Draheim whose advice about
+# the m4_case and m4_ifvaln functions make this macro only include the
+# portions necessary to perform the specific comparison specified by the
+# OP argument in the final configure script.
+#
+# LICENSE
+#
+# Copyright (c) 2008 Tim Toolan <address@hidden>
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved.
+
+dnl #########################################################################
+AC_DEFUN([AX_COMPARE_VERSION], [
+ AC_REQUIRE([AC_PROG_AWK])dnl
+
+ # Used to indicate true or false condition
+ ax_compare_version=false
+
+ # Convert the two version strings to be compared into a format that
+ # allows a simple string comparison. The end result is that a version
+ # string of the form 1.12.5-r617 will be converted to the form
+ # 0001001200050617. In other words, each number is zero padded to four
+ # digits, and non digits are removed.
+ AS_VAR_PUSHDEF([A],[ax_compare_version_A])
+ A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+ -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+ -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+ -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+ -e 's/[[^0-9]]//g'`
+
+ AS_VAR_PUSHDEF([B],[ax_compare_version_B])
+ B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+ -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+ -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+ -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+ -e 's/[[^0-9]]//g'`
+
+ dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
+ dnl # then the first line is used to determine if the condition is true.
+ dnl # The sed right after the echo is to remove any indented white space.
+ m4_case(m4_tolower($2),
+ [lt],[
+ ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+ ],
+ [gt],[
+ ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+ ],
+ [le],[
+ ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+ ],
+ [ge],[
+ ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+ ],[
+ dnl Split the operator from the subversion count if present.
+ m4_bmatch(m4_substr($2,2),
+ [0],[
+ # A count of zero means use the length of the shorter version.
+ # Determine the number of characters in A and B.
+ ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
+ ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
+
+ # Set A to no more than B's length and B to no more than A's length.
+ A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
+ B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
+ ],
+ [[0-9]+],[
+ # A count greater than zero means use only that many subversions
+ A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+ B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+ ],
+ [.+],[
+ AC_WARNING(
+ [illegal OP numeric parameter: $2])
+ ],[])
+
+ # Pad zeros at end of numbers to make same length.
+ ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
+ B="$B`echo $A | sed 's/./0/g'`"
+ A="$ax_compare_version_tmp_A"
+
+ # Check for equality or inequality as necessary.
+ m4_case(m4_tolower(m4_substr($2,0,2)),
+ [eq],[
+ test "x$A" = "x$B" && ax_compare_version=true
+ ],
+ [ne],[
+ test "x$A" != "x$B" && ax_compare_version=true
+ ],[
+ AC_WARNING([illegal OP parameter: $2])
+ ])
+ ])
+
+ AS_VAR_POPDEF([A])dnl
+ AS_VAR_POPDEF([B])dnl
+
+ dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
+ if test "$ax_compare_version" = "true" ; then
+ m4_ifvaln([$4],[$4],[:])dnl
+ m4_ifvaln([$5],[else $5])dnl
+ fi
+]) dnl AX_COMPARE_VERSION
Index: ax_need_awk.m4
===================================================================
RCS file: ax_need_awk.m4
diff -N ax_need_awk.m4
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ ax_need_awk.m4 24 Jan 2017 15:45:34 -0000 1.1
@@ -0,0 +1,37 @@
+# ===========================================================================
+# http://autoconf-archive.cryp.to/ax_need_awk.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# AX_NEED_AWK
+#
+# DESCRIPTION
+#
+# Check if an awk implementation is available. Bail-out if not found.
+#
+# This work is heavily based upon testawk.sh script by Heiner Steven. You
+# should find his script (and related works) at
+# <http://www.shelldorado.com/articles/awkcompat.html>. Thanks to
+# Alessandro Massignan for his suggestions and extensive nawk tests on
+# FreeBSD.
+#
+# LAST MODIFICATION
+#
+# 2008-04-12
+#
+# COPYLEFT
+#
+# Copyright (c) 2008 Francesco Salvestrini <address@hidden>
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved.
+
+AC_DEFUN([AX_NEED_AWK],[
+ AC_REQUIRE([AC_PROG_AWK])
+
+ AS_IF([test "x$AWK" = "x"],[
+ AC_MSG_ERROR([cannot find awk, bailing out])
+ ])
+])
Index: ax_try_awk_expout.m4
===================================================================
RCS file: ax_try_awk_expout.m4
diff -N ax_try_awk_expout.m4
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ ax_try_awk_expout.m4 24 Jan 2017 15:45:34 -0000 1.1
@@ -0,0 +1,60 @@
+# ===========================================================================
+# http://autoconf-archive.cryp.to/ax_try_awk_expout.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#
AX_TRY_AWK_EXPOUT(NAME,TEST-INPUT,TEST-BODY,EXPECTED-OUTPUT,[ACTION-IF-SUCCESS],[ACTION-IF-FAILURE])
+#
+# DESCRIPTION
+#
+# Run a test using the awk program found on AWK variable. The test being
+# run has TEST-BODY as body and is feeded with TEST-INPUT. Check if the
+# test gives the expected output. If successful execute ACTION-IF-SUCCESS
+# otherwise ACTION-IF-FAILURE.
+#
+# This work is heavily based upon testawk.sh script by Heiner Steven. You
+# should find his script (and related works) at
+# <http://www.shelldorado.com/articles/awkcompat.html>. Thanks to
+# Alessandro Massignan for his suggestions and extensive nawk tests on
+# FreeBSD.
+#
+# LAST MODIFICATION
+#
+# 2008-04-12
+#
+# COPYLEFT
+#
+# Copyright (c) 2008 Francesco Salvestrini <address@hidden>
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved.
+
+AC_DEFUN([AX_TRY_AWK_EXPOUT], [
+ AC_REQUIRE([AX_NEED_AWK])
+
+ AC_MSG_CHECKING([if $AWK supports $1])
+
+ cat <<EOF > conftest.out
+$2
+EOF
+
+ ax_try_awk_output=`$AWK '{ [$3] ; }' conftest.out 2> /dev/null`
+ ax_try_awk_result=$?
+
+ rm -f conftest.out
+
+ AS_IF([test $ax_try_awk_result -eq 0],[
+ AS_IF([test "X$ax_try_awk_output" = "X[$4]"],[
+ AC_MSG_RESULT([yes])
+ $5
+ ],[
+ AC_MSG_RESULT([no])
+ $6
+ ])
+ ],[
+ AC_MSG_RESULT([no])
+ $6
+ ])
+])
Index: check_gnu_make.m4
===================================================================
RCS file: check_gnu_make.m4
diff -N check_gnu_make.m4
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ check_gnu_make.m4 24 Jan 2017 15:45:34 -0000 1.1
@@ -0,0 +1,81 @@
+# ===========================================================================
+# http://autoconf-archive.cryp.to/check_gnu_make.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# CHECK_GNU_MAKE()
+#
+# DESCRIPTION
+#
+# This macro searches for a GNU version of make. If a match is found, the
+# makefile variable `ifGNUmake' is set to the empty string, otherwise it
+# is set to "#". This is useful for including a special features in a
+# Makefile, which cannot be handled by other versions of make. The
+# variable _cv_gnu_make_command is set to the command to invoke GNU make
+# if it exists, the empty string otherwise.
+#
+# Here is an example of its use:
+#
+# Makefile.in might contain:
+#
+# # A failsafe way of putting a dependency rule into a makefile
+# $(DEPEND):
+# $(CC) -MM $(srcdir)/*.c > $(DEPEND)
+#
+# @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
+# @ifGNUmake@ include $(DEPEND)
+# @ifGNUmake@ endif
+#
+# Then configure.in would normally contain:
+#
+# CHECK_GNU_MAKE()
+# AC_OUTPUT(Makefile)
+#
+# Then perhaps to cause gnu make to override any other make, we could do
+# something like this (note that GNU make always looks for GNUmakefile
+# first):
+#
+# if ! test x$_cv_gnu_make_command = x ; then
+# mv Makefile GNUmakefile
+# echo .DEFAULT: > Makefile ;
+# echo \ $_cv_gnu_make_command \$@ >> Makefile;
+# fi
+#
+# Then, if any (well almost any) other make is called, and GNU make also
+# exists, then the other make wraps the GNU make.
+#
+# LAST MODIFICATION
+#
+# 2008-04-12
+#
+# COPYLEFT
+#
+# Copyright (c) 2008 John Darrington <address@hidden>
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved.
+
+AC_DEFUN([CHECK_GNU_MAKE],
+[AC_REQUIRE([AC_PROG_GREP])dnl
+AC_CACHE_CHECK([for GNU make], [_cv_gnu_make_command],
+ [_cv_gnu_make_command=''
+ # Search all the common names for GNU make
+ for a in "$MAKE" make gmake gnumake ; do
+ if test -z "$a" ; then continue ; fi ;
+ if ( sh -c "$a --version" 2> /dev/null | $GREP GNU \
+ 2>&1 > /dev/null ) ; then
+ _cv_gnu_make_command=$a ;
+ break;
+ fi
+ done
+ ])
+# If there was a GNU version, then set @ifGNUmake@ to the empty string.
+if test "x$_cv_gnu_make_command" != "x" ; then
+ ifGNUmake=''
+else
+ ifGNUmake='#'
+fi
+AC_SUBST([ifGNUmake])
+])# CHECK_GNU_MAKE
[Prev in Thread] |
Current Thread |
[Next in Thread] |
- trans-coord/gnun/server/gnun/m4-external ax_che...,
Pavel Kharitonov <=