Re: NSK(OSS) compilation problem (change to m4/extensions.m4)

[Paul Eggert]

mwoehlke <address@hidden> writes:

> I would prefer
> that autoconf know that if it is on NSK/OSS ('#ifdef __TANDEM'), that
> _TANDEM_SOURCE needs to be defined.

OK, I installed this patch into gnulib; this merges the change to
Autoconf that I installed earlier there today for this.

2006-10-11  Paul Eggert  <address@hidden>

        * m4/extensions.m4 (gl_USE_SYSTEM_EXTENSIONS): Undo previous
        change, since Autoconf's version may no longer be appropriate now
        that we are using CVS Autoconf's version.  Add support for Tandem.

--- m4/extensions.m4    3 Oct 2006 04:12:40 -0000       1.11
+++ m4/extensions.m4    11 Oct 2006 23:10:59 -0000
@@ -1,4 +1,4 @@
-# serial 2  -*- Autoconf -*-
+# serial 3  -*- Autoconf -*-
 # Enable extensions on systems that normally disable them.
 
 # Copyright (C) 2003, 2006 Free Software Foundation, Inc.
@@ -6,41 +6,48 @@
 # gives unlimited permission to copy and/or distribute it,
 # with or without modifications, as long as this notice is preserved.
 
-# This file is only needed in autoconf <= 2.59.  Newer versions of autoconf
-# have a macro AC_USE_SYSTEM_EXTENSIONS with identical semantics.
+# The main body of this macro is stolen from CVS Autoconf.  Perhaps we
+# can replace it with AC_USE_SYSTEM_EXTENSIONS once we can assume
+# Autoconf 2.61 or later everywhere, but since CVS Autoconf mutates
+# rapidly enough in this area it's likely that we'll need
+# gl_USE_SYSTEM_EXTENSIONS for quite some time.
+
+# _gl_TANDEM_SOURCE
 
 # gl_USE_SYSTEM_EXTENSIONS
 # ------------------------
 # Enable extensions on systems that normally disable them,
 # typically due to standards-conformance issues.
-m4_ifdef([AC_USE_SYSTEM_EXTENSIONS],
-  [AC_DEFUN([gl_USE_SYSTEM_EXTENSIONS],
-    [AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])])],
-  [AC_DEFUN([gl_USE_SYSTEM_EXTENSIONS], [
-    AC_BEFORE([$0], [AC_COMPILE_IFELSE])
-    AC_BEFORE([$0], [AC_RUN_IFELSE])
-
-    AC_REQUIRE([AC_GNU_SOURCE])
-    AC_REQUIRE([AC_AIX])
-    AC_REQUIRE([AC_MINIX])
+AC_DEFUN([gl_USE_SYSTEM_EXTENSIONS],
+[
+  AC_BEFORE([$0], [AC_COMPILE_IFELSE])
+  AC_BEFORE([$0], [AC_RUN_IFELSE])
+
+  AC_REQUIRE([AC_GNU_SOURCE])
+  AC_REQUIRE([AC_AIX])
+  AC_REQUIRE([AC_MINIX])
 
-    AH_VERBATIM([__EXTENSIONS__],
+  AH_VERBATIM([__EXTENSIONS__],
 [/* Enable extensions on Solaris.  */
 #ifndef __EXTENSIONS__
 # undef __EXTENSIONS__
 #endif
 #ifndef _POSIX_PTHREAD_SEMANTICS
 # undef _POSIX_PTHREAD_SEMANTICS
+#endif
+#ifndef _TANDEM_SOURCE
+# undef _TANDEM_SOURCE
 #endif])
-    AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
-      [ac_cv_safe_to_define___extensions__],
-      [AC_COMPILE_IFELSE(
-         [AC_LANG_PROGRAM([
-           #define __EXTENSIONS__ 1
-           AC_INCLUDES_DEFAULT])],
-         [ac_cv_safe_to_define___extensions__=yes],
-         [ac_cv_safe_to_define___extensions__=no])])
-    test $ac_cv_safe_to_define___extensions__ = yes &&
-      AC_DEFINE([__EXTENSIONS__])
-    AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
-])])
+  AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
+    [gl_cv_safe_to_define___extensions__],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM([
+#        define __EXTENSIONS__ 1
+         AC_INCLUDES_DEFAULT])],
+       [gl_cv_safe_to_define___extensions__=yes],
+       [gl_cv_safe_to_define___extensions__=no])])
+  test $gl_cv_safe_to_define___extensions__ = yes &&
+    AC_DEFINE([__EXTENSIONS__])
+  AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
+  AC_DEFINE([_TANDEM_SOURCE])
+])