Re: ld-output-def

[Ralf Wildenhues]

Hi Simon,

a couple of nits:

* Simon Josefsson wrote on Tue, Mar 31, 2009 at 12:01:06PM CEST:
> --- /dev/null
> +++ b/m4/ld-output-def.m4

> +# gl_LD_OUTPUT_DEF()
> +# -------------
> +# Check if linker supports -Wl,--output-def and define automake
> +# conditional HAVE_LD_OUTPUT_DEF if it is.
> +AC_DEFUN([gl_LD_OUTPUT_DEF],
> +[
> +  AC_MSG_CHECKING([if gcc/ld supports -Wl,--output-def])
> +  if test "$enable_shared" = no; then
> +    output_def=no
> +    AC_MSG_RESULT([not need, since shared libraries are disabled])
> +  else
> +    _gcc_ldflags_save=$LDFLAGS

How about using the gl_ or _gl_ namespace for internal variables?

> +    LDFLAGS="-Wl,--output-def,foo.def"

How about conftest.def, to avoid your macro overwriting my precious
Foo Dictionary of Etymological Fiction, and to ensure ^C will not cause
leftover junk in my build directory?  ;-)

> +    AC_LINK_IFELSE(AC_LANG_PROGRAM([]),output_def=yes,output_def=no)

Please m4-quote [all], [macro], [arguments], but especially those that
themselves contain m4 macros, thanks!

> +    rm -f foo.def

See above.

> +    AC_MSG_RESULT($output_def)
> +    LDFLAGS="$_gcc_ldflags_save"
> +  fi
> +  AM_CONDITIONAL(HAVE_LD_OUTPUT_DEF, test "$output_def" = "yes")
> +])

Cheers,
Ralf