wmemchr on MSVC

[Bruno Haible]

On MSVC 9, we get a compilation error in gnulib's <wchar.h>
replacement, because the autoconf test has not found the wmemchr()
function - in fact, it's an inline function - and therefore
our wchar.h provides a substitute - which is in fact unnecessary.

This fixes it. Likewise for wmemcmp, wmemcpy, wmemmove, wmemset.


2011-10-03  Bruno Haible  <address@hidden>

        wmemchr: Support for MSVC.
        * m4/wmemchr.m4 (gl_FUNC_WMEMCHR): Use a small test program to test
        whether wmemchr() exists.

--- m4/wmemchr.m4.orig  Tue Oct  4 01:26:14 2011
+++ m4/wmemchr.m4       Tue Oct  4 01:01:03 2011
@@ -1,4 +1,4 @@
-# wmemchr.m4 serial 2
+# wmemchr.m4 serial 3
 dnl Copyright (C) 2011 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -7,8 +7,26 @@
 AC_DEFUN([gl_FUNC_WMEMCHR],
 [
   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
-  AC_CHECK_FUNCS_ONCE([wmemchr])
-  if test $ac_cv_func_wmemchr = no; then
+  dnl We cannot use AC_CHECK_FUNCS here, because the MSVC 9 header files
+  dnl provide this function as an inline function definition.
+  AC_CACHE_CHECK([for wmemchr], [gl_cv_func_wmemchr],
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_PROGRAM([[
+/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
+   <wchar.h>.
+   BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
+   before <wchar.h>.  */
+#include <stddef.h>
+#include <stdio.h>
+#include <time.h>
+#include <wchar.h>
+]],
+          [[return ! wmemchr ((const wchar_t *) 0, (wchar_t) ' ', 0);]])
+       ],
+       [gl_cv_func_wmemchr=yes],
+       [gl_cv_func_wmemchr=no])
+    ])
+  if test $gl_cv_func_wmemchr = no; then
     HAVE_WMEMCHR=0
   fi
 ])