[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[open-cobol-list] open cobol 1.1
|
From: |
vince |
|
Subject: |
[open-cobol-list] open cobol 1.1 |
|
Date: |
Thu, 27 Mar 2008 09:19:51 +1100 |
|
User-agent: |
KMail/1.9.7 |
I don't know if it is officially supported, but my test code with "SCREEN
SECTION" compiles without a problem. The developers have done a great job
Thanks :)
Test Code:
000000 IDENTIFICATION DIVISION.
000001*------------------------
000002******************************************************************
000003* Program Name : pmsmenu.cbl *
000004* Version No. : 1 *
000005* Language : MF/IBM/ANSI COBOL *
000006* Compiler : MS COBOL V2.0 *
000007* *
000008* Other Files : Uses the following libraries : *
000009* ----------- *
000010* addprop.cbl Adds a Property to properties data files(DB) *
000011* addowner.cbl Adds a Owner to the owners data files (DB) *
000012* delprop.cbl Delete a Property from the properties DB *
000013* delowner.cbl Deletes an Owner from the owners DB *
000014* modprop.cbl Modify an exiting Property Record *
000015* *
000016* Description : Module is ansi 85 compliant and is the main *
000017* calling program in a suite comprising the *
000018* "Property Management System" PMS *
000019* *
000020* History : *
000021* Author Date Comments *
000022* Vince Pisciotta Aug96 Assignment 1 for Advanced Cobol *
000023* Semerter 2 1996 *.
000024******************************************************************
000025 PROGRAM-ID. PMSMENU.
000026 AUTHOR. Vince-Pisciotta.
000027*
000028 ENVIRONMENT DIVISION.
000029*---------------------
000030 CONFIGURATION SECTION.
000031 SOURCE-COMPUTER. Linux_x86.
000032 OBJECT-COMPUTER. Linux_x86.
000033*
000034 DATA DIVISION.
000035*---------------
000036 WORKING-STORAGE SECTION.
000037******************************************************************
000038* WS 88 variables for determination of End of file *
000039* and file IO ststus variable . *
000040******************************************************************
000041 01 Menu-Type PIC X(10).
000042 01 Menu-Option PIC X.
000043 88 Exit-Program VALUES ARE 'Q' 'q'.
000044 88 Switch-Menu VALUES ARE 'S' 's'.
000045*
000046 SCREEN SECTION.
000047******************************************************************
000048* Definitions for the USER INPUT SCREEN *
000049******************************************************************
000050 01 Property-Screen.
000051 10 VALUE "PROPERTY MANAGEMENT SYSTEM MAIN MENU"
000052 LINE 4 COL 25.
000053 10 VALUE "ACTIVE FILE : PROPERTIES"
000054 LINE 5 COL 25.
000055 10 VALUE "1. ADD PROPERTY" LINE 7 COL 30.
000056 10 VALUE "2. DISPLAY PROPERTY DETAILS"
000057 LINE 8 COL 30.
000058 10 VALUE "3. MODIFY PROPERTY" LINE 9 COL 30.
000059 10 VALUE "4. DELETE PROPERTY" LINE 10 COL 30.
000060 10 VALUE "R. REPORTS" LINE 12 COL 30.
000061 10 VALUE "S. SWITCH TO OWNERS FILE"
000062 LINE 13 COL 30.
000063 10 VALUE "Q. QUIT" LINE 15 COL 30.
000064 10 VALUE "Please Enter Option" LINE 19 COL 10.
000065 10 PIC X(1) TO Menu-Option LINE 19 COL 30.
000067 01 Owner-Screen.
000068 10 VALUE "PROPERTY MANAGEMENT SYSTEM MAIN MENU"
000069 LINE 4 COL 25.
000070 10 VALUE "ACTIVE FILE : OWNERS"
000071 LINE 5 COL 25.
000072 10 VALUE "1. ADD OWNER" LINE 7 COL 30.
000073 10 VALUE "2. DISPLAY OWNER DETAILS"
000074 LINE 8 COL 30.
000075 10 VALUE "3. MODIFY OWNER" LINE 9 COL 30.
000076 10 VALUE "4. DELETE OWNER" LINE 10 COL 30.
000077 10 VALUE "R. REPORTS" LINE 12 COL 30.
000078 10 VALUE "S. SWITCH TO PROPERTIES FILE"
000079 LINE 13 COL 30.
000080 10 VALUE "Q. QUIT" LINE 15 COL 30.
000081 10 VALUE "Please Enter Option" LINE 19 COL 10.
000082 10 PIC X(1) TO Menu-Option LINE 19 COL 30.
000084*
000085 PROCEDURE DIVISION.
000086*-------------------
000087*
000088******************************************************************
000089* CALLED BY : NONE *
000090* *
000091* CALLS : Initialisation *
000092* Input-Processing *
000093* Termination *
000094******************************************************************
000095 Main.
000096 PERFORM Initialisation.
000097 PERFORM Option-Processing UNTIL Exit-Program.
000098 PERFORM Termination.
000099 STOP RUN.
000100*
000101******************************************************************
000102* CALLED BY : Main *
000103* *
000104* CALLS : None *
000105******************************************************************
000106 Initialisation.
000107 MOVE SPACES TO Menu-Option.
000108 ACCEPT Menu-Type FROM COMMAND-LINE.
000109 IF Menu-Type NOT = 'PROPERTIES' AND Menu-Type NOT = 'OWNER'
000110 MOVE 'PROPERTIES' TO Menu-Type.
000111* CALL X"E4".
000112*
000113******************************************************************
000114* CALLED BY : Main *
000115* *
000116* CALLS : NONE *
000117******************************************************************
000118 Option-Processing.
000119 IF Menu-Type = 'OWNER'
000120 DISPLAY Owner-Screen
000121 ACCEPT Owner-Screen
000122 ELSE
000123 DISPLAY Property-Screen
000124 ACCEPT Property-Screen
000125 END-IF.
000126 IF Switch-Menu
000127 IF Menu-Type = 'OWNER'
000128 MOVE 'PROPERTIES' TO Menu-Type
000129 ELSE
000130 MOVE 'OWNER' TO Menu-Type
000131 END-IF
000132* CALL X"E4"
000133 ELSE
000134 PERFORM External-Subroutine-Call
000135 END-IF.
000136*
000137******************************************************************
000138* CALLED BY : Main *
000139* *
000140* CALLS : NONE *
000141******************************************************************
000142 External-Subroutine-Call.
000143 IF Menu-Type = 'OWNER'
000144 EVALUATE Menu-Option
000145 WHEN '1' CALL "ADDOWN"
000146 WHEN '2' CALL "FNDOWN"
000147 WHEN '3' CALL "MODOWN"
000148 WHEN '4' CALL "DELOWN"
000149 WHEN 'R' CALL "RPTMENU"
000150 WHEN 'r' CALL "RPTMENU"
000151 END-EVALUATE
000152 ELSE
000153 EVALUATE Menu-Option
000154 WHEN '1' CALL "ADDPROP"
000155 WHEN '2' CALL "FNDPROP"
000156 WHEN '3' CALL "MODPROP"
000157 WHEN '4' CALL "DELPROP"
000158 WHEN 'R' CALL "RPTMENU"
000159 WHEN 'r' CALL "RPTMENU"
000160 END-EVALUATE
000161 END-IF.
000162*
000163******************************************************************
000164* CALLED BY : Main *
000165* Initialisation *
000166* *
000167* CALLS : NONE *
000168******************************************************************
000169 Termination.
000170 DISPLAY ' '.
000171 DISPLAY ' '.
000172 DISPLAY ' '.
000173 DISPLAY ' '.
000174 DISPLAY ' ********************'.
000175 DISPLAY ' * PROGRAM COMPLETE *'.
000176 DISPLAY ' ********************'.
000177 DISPLAY ' '.
-------------------------------------------------------
| [Prev in Thread] |
Current Thread |
[Next in Thread] |
- [open-cobol-list] open cobol 1.1,
vince <=