Re: Rmail tips

[Fernando de Morais]

Hello Ben,

I believe this answer is long overdue and now, after a few months of
use, you should have already configured RMAIL to suit your needs.

However, here are some recommendations for things that were helpful to
me when using RMAIL:

1. Quick jumps between `rmail-summary' and `rmail' buffers:

The next two functions can help with navigation by allowing a quick
switch between RMAIL buffers.

#+begin_src emacs-lisp
(defun rmail-jump-to-summary ()
  "Jump to summary window that corresponds to `rmail'."
  (interactive)
  (let ((rmail-summary-window (get-buffer-window rmail-summary-buffer)))
    (if rmail-summary-window
        (select-window rmail-summary-window)
      (user-error "No summary window associated with this RMAIL window"))))

(defun rmail-summary-jump-to-rmail ()
  "Jump to RMAIL window that corresponds to `rmail-summary'."
  (interactive)
  (let ((rmail-window (get-buffer-window rmail-buffer)))
    (if rmail-window
        (select-window rmail-window)
      (user-error "No RMAIL window associated with this summary"))))
#+end_src

I commonly bind them to the "J" key in the `rmail-mode-map' and
`rmail-summary-mode-map' maps, respectively.

2. Using Mairix as an email indexer and search engine:

Even if you only ever work with a single mbox file, I highly recommend
using Mairix. It is small, simple and easy to configure.  Additionally,
Emacs has an integrated interface[1] that can be easily associated with
your RMAIL configurations.

As an example:

#+begin_src emacs-lisp
(with-eval-after-load 'rmail
  (when (require 'mairix nil t)
    (define-prefix-command 'rmail-mairix-map)
    (define-key rmail-mode-map "M" #'rmail-mairix-map)
    (let ((map 'rmail-mairix-map))
      (define-key map "E" #'mairix-edit-saved-searches)
      (define-key map "S" #'mairix-save-search)
      (define-key map "U" #'mairix-use-saved-search)
      (define-key map "b" #'mairix-widget-search-based-on-article)
      (define-key map "f" #'mairix-search-from-this-article)
      (define-key map "s" #'mairix-search)
      (define-key map "t" #'mairix-search-thread-this-article)
      (define-key map "u" #'mairix-update-database)
      (define-key map "w" #'mairix-widget-search))
    (with-eval-after-load 'rmailsum
      (define-key rmail-summary-mode-map "M" #'rmail-mairix-map))))
#+end_src

3. Some other settings/comments worth taking a look at:

Göktuğ Kayaalp[2] and Alex Schroeder's[3] settings helped me get the hang of
RMAIL. Maybe it will be an interesting read for you.

Hope it helps!

Footnotes:
[1]  (info "(mairix-el) Top")

[2]  https://cadadr.dreamwidth.org/828.html

[3]  https://alexschroeder.ch/view/2020-12-17_Rmail#main

-- 
Regards,
Fernando de Morais.