emacs-orgmode
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: [O] how to select a source code block and print it to a postscript f


From: dmg
Subject: Re: [O] how to select a source code block and print it to a postscript file
Date: Sat, 9 Sep 2017 14:57:43 -0700

I invested a bit more time (plus a couple of suggestions of members of this list and stackoverflow.) I was able to create a module that prints the current source block to PDF
without using the exporter. It now uses the pdf viewer to open it.

It might be useful to some people who simply need to create a PDF from a source block and have it open in the corresponding PDF application:


I look at your suggestions, which pointed me in the direction I needed.
At the end I realized what I wanted was simply to export the current
block to PDF without using the latex exporter. So I simply make the
selection and print that selection to ps, then convert to pdf, and open
using org-open



----------------------------------------------------------------------
(defcustom dmg-org-src-export-pdf-font-size 12
   "Size of font to use "
  :type 'number
  :version 25
  :group 'dmg-org-src-export-pdf)

(defcustom dmg-org-src-export-pdf-file-name "/tmp/source.code"
   "Name of the file to export as postscript "
  :type 'string
  :version 25
  :group 'dmg-org-src-export-pdf)


(defun dmg-org-src-export-pdf ()
  "show the source code in xournal as a PDF"
  (interactive)
  (save-restriction
    (save-excursion
       (unless (executable-find "ps2pdf") 
          (error "ps2pdf not found"))

      (let ((element (org-element-at-point))
            )
        (unless (eq (org-element-type element) 'src-block)
          (error "Not in org-src-block"))
        )

      (let* (
             (output-file
              (or (cdr (assq :tangle (nth 2 (org-babel-get-src-block-info 'light))))
                  dmg-org-src-export-pdf-file-name))
             (ps-file (concat output-file ".ps"))
             (pdf-file (concat output-file ".pdf"))
             ;; this uses dynamic scoping to set the parameters of ps temporarily
             (ps-font-size dmg-org-src-export-pdf-font-size)
             )
        (message "Exporting: %s" ps-file)
        (org-babel-mark-block)
        (narrow-to-region (region-beginning) (region-end))
        (ps-print-buffer-with-faces  ps-file)
        (shell-command (concat "ps2pdf " ps-file " " pdf-file))
        (delete-file ps-file)
        (org-open-file pdf-file)
        )
      )))


On Sat, Sep 9, 2017 at 2:25 AM, dmg <address@hidden> wrote:
hi everybody,

I teach programming and I have been using org-mode for a couple years to do it. I absolutely love it.
Lately I have been thinking that I would like to be able to draw on the source code using xournal
(using a tablet)

To do that, I need to generate a pdf. But I don't want to generate the PDF of the entire file,
just of the block I am currently positioned at. I wrote the following code, but it feels clumsy, and
I am not a very good emacs-lisp programmer. I put it together by extracting code here and there.

Is there a better way to run ps-print-buffer (or ps-print-region) on the current block?
I am currently using the :tangle parameter as a filename to be created (adding the extension .ps)

the script I am running takes the postscript file, generate a pdf, and then runs xournal on it.

thank you in advance for any suggestions,

(defun org-src-xournal ()
  "show the source code in xournal as a PDF"
  (interactive)
  (save-restriction
    (save-excursion
      (let* ((case-fold-search t)
            (tangle-file
             (or (cdr (assq :tangle (nth 2 (org-babel-get-src-block-info 'light))))
                 (user-error "Point is not in a source code block or it does not have a tangle name")))
            (blockp (org-between-regexps-p "^[ \t]*#\\+begin_.*"
                                           "^[ \t]*#\\+end_.*"))
            (ps-file (concat tangle-file ".ps"))
            )
        
        (message "Exporting: %s" ps-file)
        (if blockp
            (let ((block-start 
                    (progn (goto-char (car blockp))
                        (next-line)
                        (point)
                      ))
                  (block-end
                    (progn (goto-char (cdr blockp))
                        (previous-line)
                        (point)
                      ))
                  )
              (narrow-to-region block-start block-end))
          (user-error "Not in a block"))
        (ps-print-buffer-with-faces ps-file)
        (shell-command (concat "code-xournal " ps-file "&"))
        )
      )))


--
--dmg

---
Daniel M. German
http://turingmachine.org



--
--dmg

---
Daniel M. German
http://turingmachine.org

reply via email to

[Prev in Thread] Current Thread [Next in Thread]